
; Тестовый загрузчик игры перевал.
; использует оригинальные данные.
; Сперва загрузчик переносится в область 137000
; затем грузится игра и переносится на свой адрес
; затем грузится заставка в экран

; переносим загрузчик на адрес 137000
            mov     #137000, R0
            mov     R0, R5
            mov     #MV1B$, R1
            mov     #<MV1E$ - MV1B$> / 2, R2
2$:         mov     (R1)+, (R0)+
            sob     R2, 2$
            jmp     (R5)
; загружаем игру
MV1B$:      mtps    #340
            mov     #137776, SP
            .addr   R1, GMEBPM
            call    @#120002
            tstb    1(R1)
            beq     3$
            halt
3$:         mov     #26070, SP
; переносим на своё место
            mov     #1000, R1
            mov     #20000, R2
            clr     R0
4$:         mov     (R1)+, (R0)+
            sob     R2, 4$
            .addr   R1, PICBPM
            call    @#120002
            ; восстанавливаем испорченные ячейки
            mov     #160401, @#52
            mov     #24552, @#264
            mov     #177, @#266
            mov     #7054, @#300
            ; бессмертие
            mov #402,@#30532
            mov #457,@#30232
            mov #33767, @#30234
            ; исправление ошибок
            ; ПОКА НЕТУ
            jmp     @#25164
PICBPM:     .word   3
            .word   40000,0
            .asciz  "PEREVAL.PIC"
            .even
            .blkb   30
GMEBPM:     .word   3
            .word   1000,0
            .asciz  "PEREVAL.GME"
            .even
            .blkb   30

MV1E$:



            .end