;делатель нового РМ3 фонта из стандартного БК11Много
        mov     #56000,@#177716
        mov     #10000,R1
1$:     clr     (R1)+
        cmp     r1,#40000
        blo     1$
        mov     #10000,R4
        mov     #40,R0      ;сперва 40 фейковых символов
2$:     mov     #50000,R5
        call    getsym
        sob     r0,2$
        ;затем остальные 340 настоящих
        mov     #50000,R5   ;начало бкшного фонта
        mov     #340,R0     ;кол-во знаков в фонте.
3$:     call    getsym
        sob     r0,3$
        sub     #10000,R4
        mov     #16000,@#177716
        mov     r4,BPAR+4
        mov     #BPAR,R1
        emt     36
        halt

;вход: R4 - адрес приёмника
;R5 - адрес источника.
;из символа шириной байт, высотой 12 строк
;делаем символ шириной слово, высотой 10 строк.
GETSYM: mov     r0,-(sp)
        inc     R5
        mov     #10,R3
2$:     movb    (r5)+,r0
        mov     #10,R2
1$:     ror     R0
        ror     R1
        asr     R1
        sob     R2,1$
        mov     R1,(r4)+
        sob     R3,2$
        inc     r5
        mov     (sp)+,R0
        return





BPAR:   .word   2
        .word   10000
        .word   0
        .asciz  "BKFONTW.FNT"
        .even
        .blkw   20

        .END

        
